Скопируйте текст из Emacs в буфер обмена OS X

Когда я запускаю Emacs в текстовом терминале вместо обычного режима графического интерфейса, я могу скопировать в Emacs, активировав начало области с помощью C-SPC, а затем выбрать то, что я хочу, и затем сделать M-w.

Есть ли какой-нибудь способ получить регион, скопированный таким образом, который будет доступен в буфере обмена OSX, чтобы вставить его, скажем, на веб-страницу (очевидно, кроме запуска Emacs в режиме графического интерфейса)?

Я не заинтересован в создании другого ярлыка для этого, и в идеале для этого не нужно устанавливать какие-либо модули.

Я видел этот пост и попробовал принятый ответ, но он не работает, кажется, работает так, как я ожидал выше.

Есть еще идеи?

Скопируйте из Emacs в буфер обмена OS X:

затем выберите регион M-| pbcopy RET

Вставить из буфера обмена OS X в Emacs:

C-u M-| pbpaste RET (заменяет текущий регион, если он существует)

Объяснение:

M-|run shell-command-on-region, который, как следует из названия, передает текущую область в команду оболочки. C-u M-|делает то же самое, но заменяет текущую область stdoutкомандой запуска.

pbcopyи pbpasteутилиты OS X для доступа к системному буферу обмена.

Следующее просто работает, скопировано отсюда

(defun copy-from-osx ()
  (shell-command-to-string "pbpaste"))

(defun paste-to-osx (text &optional push)
  (let ((process-connection-type nil))
    (let ((proc (start-process "pbcopy" "*Messages*" "pbcopy")))
      (process-send-string proc text)
      (process-send-eof proc))))

(setq interprogram-cut-function 'paste-to-osx)
(setq interprogram-paste-function 'copy-from-osx)

Если вы используете Emacs «обычным способом» (то есть как приложение с графическим интерфейсом), то он должен сделать это по умолчанию. Если вы используете Emacs внутри эмулятора терминала, то он действительно не знает, как это сделать по умолчанию, но вы можете установить xclipпакет из GNU ELPA и затем включить тот, xclip-modeкоторый учит Emacs, как это делать как для GNU / Linux, так и для OSX.

Как сказал Стефан, графические приложения Emacs должны делать это по умолчанию.

В текстовом терминале другой вариант заключается в использовании таких функций:

(defun pbcopy ()
  (interactive)
  (let ((deactivate-mark t))
    (call-process-region (point) (mark) "pbcopy")))

(defun pbpaste ()
  (interactive)
  (call-process-region (point) (if mark-active (mark) (point)) "pbpaste" t t))

(defun pbcut ()
  (interactive)
  (pbcopy)
  (delete-region (region-beginning) (region-end)))

Вот простая функция elisp, которую вы можете поместить в свой файл .emacs, который копирует содержимое буфера, в котором вы находитесь, в буфер обмена. Вам не нужно ничего выбирать, он копирует все это. Код короткий и довольно понятный.

(defun xclip ()
(interactive)
(shell-command (concat "cat " (buffer-file-name (window-buffer (minibuffer-selected-window))) " | pbcopy")))

Проверьте clipboard-kill-regionи clipboard-yank. Они приходят из menu-bar.el.

Как только область выделена, вы можете использовать clipboard-kill-region для уничтожения области как в буфер вставки, так и в системный буфер обмена. clipboard-yank "вставляет" все, что в данный момент находится в системном буфере обмена.

Ответ Галдера Замарреньо велик, однако он нарушает putповедение, подобное злу, в режиме зла. Поэтому я адаптировал это немного ниже - я уверен, что это могло бы быть лучше, но это делает работу для меня. Не стесняйтесь предлагать улучшения:

(defun copy-from-osx ()
  (shell-command-to-string "pbpaste"))

(defun paste-to-osx (text &optional push)
  (let ((process-connection-type nil))
    (let ((proc (start-process "pbcopy" "*Messages*" "pbcopy")))
      (process-send-string proc text)
      (process-send-eof proc))))

----> Новый код

  (defun clipboard-on ()
    (interactive)
    (setq interprogram-cut-function 'paste-to-osx)
    (setq interprogram-paste-function 'copy-from-osx))
  (defun clipboard-off ()
    (interactive)
    (setq interprogram-cut-function 'gui-select-text)
    (setq interprogram-paste-function 'gui-selection-value))
  (global-set-key (kbd "C-c C-p") 'clipboard-on)
  (global-set-key (kbd "C-c C-y") 'clipboard-off))