Как определить размер моих таблиц в базе данных SQL Server

Существует ли какая-либо встроенная функция / хранимая процедура / запрос, которая полезна для получения информации о размере MyTable базы данных SQL Server?

Для одного стола вы можете использовать

sp_spaceused MyTable

Для всех таблиц в базе данных вы можете использовать его в sp_msforeachtableкачестве следующего

CREATE TABLE #temp (
table_name sysname ,
row_count INT,
reserved_size VARCHAR(50),
data_size VARCHAR(50),
index_size VARCHAR(50),
unused_size VARCHAR(50))
SET NOCOUNT ON
INSERT #temp
EXEC sp_msforeachtable 'sp_spaceused ''?'''
SELECT a.table_name,
a.row_count,
COUNT(*) AS col_count,
a.data_size
FROM #temp a
INNER JOIN information_schema.columns b
ON a.table_name collate database_default
= b.table_name collate database_default
GROUP BY a.table_name, a.row_count, a.data_size
ORDER BY CAST(REPLACE(a.data_size, ' KB', '') AS integer) DESC
DROP TABLE #temp

Если вы не хотите писать сценарий, вы также можете открыть слишком малоиспользуемые «Детали проводника объектов» в SSMS (комбинация клавиш F7).

На верхнем уровне откройте папку «Таблицы», чтобы получить список всех таблиц в вашей базе данных.

Возможно, вам придется настроить столбцы, чтобы увидеть используемое пространство. Это можно сделать, щелкнув правой кнопкой мыши строку заголовка и выбрав столбцы, которые вы хотите отобразить.

В «Обозревателе объектов» доступно гораздо больше таких данных.

В SSMS щелкните правой кнопкой мыши на базе данных, выберите Отчеты, Стандартные отчеты, Использование диска по верхним таблицам.

В отчете будет указано количество строк и килобайт, использованных в таблице.

Посмотрите на sys.dm_db_partition_stats ( http://msdn.microsoft.com/en-us/library/ms187737.aspx ).

По этой ссылке, а также по адресу http://blogs.msdn.com/b/cindygross/archive/2010/04/02/dmv-series-sys-dm-db-partition-stats.aspx есть несколько примеров запросов.

Вы можете изменить в соответствии с вашими потребностями, т.е. фильтровать входящие / исходящие некластеризованные индексы. Умножьте количество страниц на 8, чтобы получить размер в КБ, затем разделите на 2 ^ 10 (= 1024), чтобы преобразовать в МБ при необходимости.

sp_spaceused ( http://msdn.microsoft.com/en-us/library/ms188776.aspx ) также предоставит информацию о размере таблицы.

Чтобы получить информацию о размере таблицы, я хотел бы использовать следующий скрипт

SELECT  sc.name + '.' + t.NAME AS TableName,  
        p.[Rows],  
        ( SUM(a.total_pages) * 8 ) / 1024 AS TotalReservedSpaceMB, -- Number of total pages * 8KB size of each page in SQL Server  
        ( SUM(a.used_pages) * 8 ) / 1024 AS UsedDataSpaceMB,  
        ( SUM(a.data_pages) * 8 ) / 1024 AS FreeUnusedSpaceMB  
FROM    msdb.sys.tables t  
        INNER JOIN msdb.sys.schemas sc ON sc.schema_id = t.schema_id  
        INNER JOIN msdb.sys.indexes i ON t.OBJECT_ID = i.object_id  
        INNER JOIN msdb.sys.partitions p ON i.object_id = p.OBJECT_ID  
                                            AND i.index_id = p.index_id  
        INNER JOIN msdb.sys.allocation_units a ON p.partition_id = a.container_id  
WHERE   t.type_desc = 'USER_TABLE'  
        AND i.index_id <= 1  --- Heap\ CLUSTERED
        AND t.NAME='MYTableName' -- Replace with valid table name
GROUP BY sc.name + '.' + t.NAME,  
        i.[object_id],i.index_id, i.name, p.[Rows]  
ORDER BY ( SUM(a.total_pages) * 8 ) / 1024 DESC  

Перейдите в базу данных, затем щелкните правой кнопкой мыши и выберите отчеты, затем стандартные отчеты, затем использование диска по таблицам. Это даст вам все файлы в этой базе данных и их записи, данные, индексы и т. Д.

Вы можете использовать следующий скрипт, который вычисляет объем для каждой таблицы и другой набор результатов общего количества для базы данных

    SET NOCOUNT ON 
    IF OBJECT_ID('tempdb..#SpaceUsed') IS NOT NULL DROP TABLE #SpaceUsed

    CREATE TABLE #SpaceUsed 
    (
    TableName sysname ,
    [Rows] int ,
    [Reserved] varchar(20),
    [Data] varchar(20),
    [Index_Size] varchar(20),
    [Unused] varchar(20),
    [Reserved_KB] bigint,
    [Data_KB] bigint,
    [Index_Size_KB] bigint,
    [Unused_KB] bigint
    )

    DECLARE @CMD NVARCHAR(MAX) =''
    SELECT @CMD +='EXEC sp_spaceused ' +  ''''+QUOTENAME(TABLE_SCHEMA)+'.'+ QUOTENAME(TABLE_NAME)+''''+';'+CHAR(10)
    FROM INFORMATION_SCHEMA.TABLES 
    --PRINT @CMD

     INSERT INTO #SpaceUsed (TableName ,[Rows] , [Reserved], [Data] , [Index_Size] , [Unused] )
     EXEC sp_executesql @CMD



     UPDATE #SpaceUsed 
     SET [Reserved_KB] = CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Reserved] , ' KB', '')))),
         [Data_KB] = CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Data] , ' KB', '')))),
         [Index_Size_KB]= CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Index_Size] , ' KB', '')))),
         [Unused_KB]= CONVERT(BIGINT,RTRIM(LTRIM(REPLACE([Unused] , ' KB', ''))))


     SELECT TableName, [Rows], Reserved_KB , Data_KB , Index_Size_KB , Unused_KB ,  Data_KB / 1024.0 Data_MB , Data_KB / 1024.0 / 1024.0 Data_GB
     FROM #SpaceUsed
     ORDER BY Data_KB DESC 

     SELECT SUM(Reserved_KB) Reserved_KB , SUM(Data_KB) Data_KB, SUM(Index_Size_KB) Index_Size_KB , SUM(Unused_KB) Unused_KB ,SUM(Data_KB / 1024.0) Data_MB , SUM(Data_KB / 1024.0 / 1024.0) Data_GB
     FROM #SpaceUsed

     DROP TABLE #SpaceUsed