Транзакция и Try-catch в задании SQL Server

У нас есть операции DML на каждом этапе работы SQL Server. Для того, чтобы обеспечить обновление / вставка будет откат в случае что - то пойдет не так, я завернула изменения данных о каждом шаге в TRY CATCHи TRANSACTIONблоков:

BEGIN TRY
    BEGIN TRANSACTION

        [[INSERT/update statements]] ...

    IF @@TRANCOUNT > 0
    BEGIN
        COMMIT TRANSACTION
        PRINT 'Successful.'
    END

END TRY

BEGIN CATCH
    SELECT
        ERROR_NUMBER() AS ErrorNumber,
        ERROR_SEVERITY() AS ErrorSeverity,
        ERROR_STATE() AS ErrorState,
        ERROR_PROCEDURE() AS ErrorProcedure,
        ERROR_LINE() AS ErrorLine,
        ERROR_MESSAGE() AS ErrorMessage

    IF @@TRANCOUNT > 0
    BEGIN
        ROLLBACK TRANSACTION
        PRINT 'Unsuccessful.'
    END
END CATCH

Гарантирует ли это, что манипуляции с данными будут отменены в случае ошибок? Или другие соображения должны быть приняты во внимание?

Будет ли лучший способ сделать это (используя конфигурации и т. Д.)?

Спасибо.

Я бы лучше порекомендовал шаблон, подобный тому, который используется для обработки исключений и вложенных транзакций :

create procedure [usp_my_procedure_name]
as
begin
    set nocount on;
    declare @trancount int;
    set @trancount = @@trancount;
    begin try
        if @trancount = 0
            begin transaction
        else
            save transaction usp_my_procedure_name;

        -- Do the actual work here

lbexit:
        if @trancount = 0   
            commit;
    end try
    begin catch
        declare @error int, @message varchar(4000), @xstate int;
        select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
        if @xstate = -1
            rollback;
        if @xstate = 1 and @trancount = 0
            rollback
        if @xstate = 1 and @trancount > 0
            rollback transaction usp_my_procedure_name;

        raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
    end catch   
end

Этот шаблон проверяет XACT_STATE()блок catch для защиты от незавершенных транзакций :

Uncommittable транзакции и XACT_STATE
Если ошибка, сгенерированная в блоке TRY, приводит к тому, что состояние текущей транзакции становится недействительным, транзакция классифицируется как незафиксированная транзакция. Ошибка, которая обычно завершает транзакцию вне блока TRY, приводит к тому, что транзакция переходит в состояние uncommittable, когда ошибка происходит внутри блока TRY. Нефиксированная транзакция может выполнять только операции чтения или ROLLBACK TRANSACTION. Транзакция не может выполнить какие-либо операторы Transact-SQL, которые бы генерировали операцию записи или COMMIT TRANSACTION. Функция XACT_STATE возвращает значение -1, если транзакция была классифицирована как незафиксированная транзакция. Когда пакет завершается, компонент Database Engine откатывает любые активные незафиксированные транзакции. Если сообщение об ошибке не было отправлено, когда транзакция перешла в состояние uncommittable, По завершении пакета клиентскому приложению будет отправлено сообщение об ошибке. Это указывает на то, что незафиксированная транзакция была обнаружена и откатана.

Ваш код проверяется @@TRANCOUNTв тех местах, где он не может быть равен 0, он использует смесь информационных сообщений PRINT и наборов результатов SELECT для сообщения об успехе, он не обрабатывает ошибки, которые можно исправить. В идеале исключения должны распространяться на клиента, в данном случае на задание агента (т. Е. Ваш улов должен быть повышен).

То, что у тебя есть, выглядит хорошо для меня. Я бы предложил сделать что-то с информацией, конечно, после того, как вы откатили транзакцию, например, запишите это в журнал.