Показать данные и использование диска в разбивке по таблицам

У меня есть база данных SQL Server 2008 R2, используемая несколькими развернутыми программами.

Вопрос: Есть ли простой способ показать, сколько места занимает каждая таблица, для всех таблиц в базе данных, и отличить логическое пространство от дискового пространства?

Если я использую SSMS (Management Studio), свойства хранилища, показанные для базы данных, будут отображать 167 МБ с 3 МБ «доступными» (примерно подходящего размера, но меня беспокоят доступные 3 МБ - стоит ли беспокоиться об этом ограничении) , если я знаю, что у меня достаточно места на диске?)

Я могу углубиться в каждый стол, но это займет вечность.

Я знаю, что могу написать свои собственные запросы и протестировать их, но я хотел бы знать, есть ли уже простой (встроенный?) Способ сделать это.

В SSMS щелкните правой кнопкой мыши базу данных и выберите «Отчеты», «Стандартные отчеты», «Использование диска по таблице». Он сообщит вам общий размер, размер данных, размер индекса и неиспользуемый размер для каждой таблицы (а также количество строк).

На вопрос переполнения стека ответили :

SELECT 
    t.NAME AS TableName,
    s.Name AS SchemaName,
    p.rows AS RowCounts,
    SUM(a.total_pages) * 8 AS TotalSpaceKB, 
    SUM(a.used_pages) * 8 AS UsedSpaceKB, 
    (SUM(a.total_pages) - SUM(a.used_pages)) * 8 AS UnusedSpaceKB
FROM 
    sys.tables t
INNER JOIN      
    sys.indexes i ON t.OBJECT_ID = i.object_id
INNER JOIN 
    sys.partitions p ON i.object_id = p.OBJECT_ID AND i.index_id = p.index_id
INNER JOIN 
    sys.allocation_units a ON p.partition_id = a.container_id
LEFT OUTER JOIN 
    sys.schemas s ON t.schema_id = s.schema_id
WHERE 
    t.NAME NOT LIKE 'dt%' 
    AND t.is_ms_shipped = 0
    AND i.OBJECT_ID > 255 
GROUP BY 
    t.Name, s.Name, p.Rows
ORDER BY 
    t.Name

Запрос, связанный и скопированный @Nelson, является неточным: он игнорирует индексированные представления, полнотекстовые индексы, XML-индексы и т. Д.

Если вы хотите запрос, который будет включать в себя все без выполнения sp_spaceusedчерез sp_MSForEachTable, то я уже опубликовал два его варианта (один здесь на DBA.StackExchange, а другой на StackOverflow), поэтому я не буду копировать их здесь:

• Для каждой таблицы / индексированного представления: sp_spaceused - Как измерить размер в ГБ во всех таблицах в SQL

• Для каждого индекса: использование пространства на sys.allocation_units и sp_spaceused

Просто для удовольствия, вот запрос, который будет генерировать те же данные, что и отчет в ответе nateirvin

create table #disk_usage
(
    name varchar(128)
    ,rows varchar(20)
    ,reserved varchar(20)
    ,data varchar(20)
    ,index_size varchar(20)
    ,unused varchar(20)
);

exec sp_msforeachtable 'insert into #disk_usage exec sp_spaceused [?]'

select SCHEMA_NAME(st.schema_id) + '.' + du.name 'Table Name'
 ,du.rows '# Records'
 ,du.reserved 'Reserved (KB)'
 ,du.data 'Data (KB)'
 ,du.index_size 'Indexes (KB)'
 ,du.unused 'Unused (KB)'
 from #disk_usage du
left join sys.tables st
on du.name = st.name
order by cast(left(reserved, len(reserved) - 3) as bigint) desc;

drop table #disk_usage

Хорошо, потому что я действительно ненавижу себя, я написал запрос, который сгенерирует результаты отчета, отформатирует его в виде таблицы HTML и отправит по электронной почте. Сопоставление цветов фона отчета оставлено читателю в качестве упражнения.

declare @subject nvarchar(25) = 'Disk Usage by Top Tables';

declare @recipients nvarchar(25) = 'mailbox@example.com';

create table #disk_usage
(
    name varchar(128)
    ,rows varchar(20)
    ,reserved varchar(20)
    ,data varchar(20)
    ,index_size varchar(20)
    ,unused varchar(20)
);

exec sp_msforeachtable 'insert into #disk_usage EXEC sp_spaceused [?]'

declare @body nvarchar(max) = 
'<table cellspacing="0">
    <thead>
        <tr>
            <th>Table Name</th>
            <th># Rows</th>
            <th>Reserved</th>
            <th>Data</th>
            <th>Indexes</th>
            <th>Unused</th>
        </tr>
    </thead>
';

set @body = @body + cast (
    (select '<td style="border: 1px solid black; padding: 2px">' + SCHEMA_NAME(s.schema_id) + '.' + t.name + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + rtrim(ltrim(t.rows)) + ' Rows </td>' -- for some reason this was generating a bunch of extra white space and I'm not going to bother to figure out why
     ,'<td style="border: 1px solid black; padding: 2px">' + t.reserved + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + t.data + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + t.index_size + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + t.unused + '</td>'
     from #disk_usage t
    left join sys.tables s
    on t.name = s.name
    order by cast(left(reserved, len(reserved) - 3) as bigint) desc
    for xml path ('tr'))
as nvarchar(max));

set @body = replace(replace(@body, '&lt;', '<'), '&gt;', '>')
set @body = @body + '</table>'

exec msdb.dbo.sp_send_dbmail 
@profile_name='A Database Mail Profile On The Target Server', 
@recipients=@recipients, 
@subject=@subject,
@body=@body,
@body_format='HTML'

drop table #disk_usage