Шаг 1. Создайте сервис для получения уведомлений и очереди для него:
use msdb;
go
create queue dbm_notifications_queue;
create service dbm_notification_service
on queue dbm_notifications_queue
([http://schemas.microsoft.com/SQL/Notifications/PostEventNotification]);
go
create event notification dbm_notifications
on server
for database_mirroring_state_change
to service N'dbm_notification_service', N'current database';
go
Обратите внимание, что я использую msdb, это не случайно. Поскольку уведомления о событиях на уровне сервера отправляются с msdbнего, гораздо лучше, если вы создадите противоположную конечную точку диалога (цель) также в msdb, что означает, что служба назначения и очередь также должны быть развернуты в msdb.
Шаг 2: создайте процедуру обработки уведомления о событии:
use msdb;
go
create table dbm_notifications_errors (
incident_time datetime not null,
session_id int not null,
has_rolled_back bit not null,
[error_number] int not null,
[error_message] nvarchar(4000) not null,
[message_body] varbinary(max));
create clustered index cdx_dbm_notifications_errors
on dbm_notifications_errors (incident_time);
go
create table mirroring_alerts (
alert_time datetime not null,
start_time datetime not null,
processing_time datetime not null,
database_id smallint not null,
database_name sysname not null,
[state] tinyint not null,
[text_data] nvarchar(max),
event_data xml not null);
create clustered index cdx_mirroring_alerts
on mirroring_alerts (alert_time);
go
create procedure dbm_notifications_procedure
as
begin
declare @dh uniqueidentifier, @mt sysname, @raw_body varbinary(max), @xml_body xml;
begin transaction;
begin try;
receive top(1)
@dh = conversation_handle,
@mt = message_type_name,
@raw_body = message_body
from dbm_notifications_queue;
if N'http://schemas.microsoft.com/SQL/Notifications/EventNotification' = @mt
begin
set @xml_body = cast(@raw_body as xml);
-- shred the XML and process it accordingly
-- IMPORTANT! IMPORTANT!
-- DO NOT LOOK AT sys.database_mirroring
-- The view represents the **CURRENT** state
-- This message reffers to an **EVENT** that had occured
-- the current state may or may no be relevant for this **PAST** event
declare @alert_time datetime
, @start_time datetime
, @processing_time datetime = getutcdate()
, @database_id smallint
, @database_name sysname
, @state tinyint
, @text_data nvarchar(max);
set @alert_time = @xml_body.value (N'(//EVENT_INSTANCE/PostTime)[1]', 'DATETIME');
set @start_time = @xml_body.value (N'(//EVENT_INSTANCE/StartTime)[1]', 'DATETIME');
set @database_id = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseID)[1]', 'SMALLINT');
set @database_name = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseName)[1]', 'SYSNAME');
set @state = @xml_body.value (N'(//EVENT_INSTANCE/State)[1]', 'TINYINT');
set @text_data = @xml_body.value (N'(//EVENT_INSTANCE/TextData)[1]', 'NVARCHAR(MAX)');
insert into mirroring_alerts (
alert_time,
start_time,
processing_time,
database_id,
database_name,
[state],
text_data,
event_data)
values (
@alert_time,
@start_time,
@processing_time,
@database_id,
@database_name,
@state,
@text_data,
@xml_body);
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/Error' = @mt
begin
set @xml_body = cast(@raw_body as xml);
DECLARE @error INT
, @description NVARCHAR(4000);
WITH XMLNAMESPACES ('http://schemas.microsoft.com/SQL/ServiceBroker/Error' AS ssb)
SELECT @error = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Code)[1]', 'INT'),
@description = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Description)[1]', 'NVARCHAR(4000)');
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
0,
@error,
@description,
@raw_body);
end conversation @dh;
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/EndDialog' = @mt
begin
end conversation @dh;
end
commit;
end try
begin catch
declare @xact_state int = xact_state(),
@error_number int = error_number(),
@error_message nvarchar(4000) = error_message(),
@has_rolled_back bit = 0;
if @xact_state = -1
begin
-- Doomed transaction, it must rollback
rollback;
set @has_rolled_back = 1;
end
else if @xact_state = 0
begin
-- transaction was already rolled back (deadlock?)
set @has_rolled_back = 1;
end
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
@has_rolled_back,
@error_number,
@error_message,
@raw_body);
if (@has_rolled_back = 0)
begin
commit;
end
end catch
end
go
Написание процедуры брокера службы не является вашим заурядным кодом. Нужно следовать определенным стандартам и очень легко заблудиться на территории зыбучих песков. Этот код показывает некоторые хорошие практики:
- обернуть сообщение очереди и обработки в транзакции. Понятно, понятно.
- всегда проверяйте тип полученного сообщения. Процедура брокера хороший сервис должен обрабатывать
Errorи EndDialogсообщения надлежащим образом путем прекращения диалога от его стороны. Невыполнение этого приводит к утечке ручки ( sys.conversation_endpointsрастет)
- всегда проверяйте, было ли сообщение удалено из команды RECEIVE. Некоторые примеры проверяют @@ rowcount after
RECEIVE, что совершенно нормально. Этот пример кода основан на проверке имени сообщения (ни одно сообщение не подразумевает имя типа сообщения NULL) и обрабатывает этот случай неявно.
- создать таблицу ошибок обработки. Фоновая природа процедур, активируемых SSB, действительно затрудняет поиск и устранение ошибок, если сообщения просто исчезают без трассировки.
Кроме того, этот код также выполняет полезный код с учетом поставленной задачи (мониторинг DBM):
- различать
post_time( когда было отправлено уведомление? ), start_time( когда началось действие, инициировавшее уведомление? ) и processing_time( когда было обработано уведомление? ). post_timeи start_time, вероятно, будут идентичны или очень близки, но processing_timeмогут быть секундами, часами, днями, кроме post_time. интересным для аудита обычно является post_time.
- Поскольку
post_timeи processing_timeотличаются, должно быть очевидно, что задача мониторинга DBM в процедуре, даже активированной уведомлением , не имеет никакого отношения к sys.database_mirroringпросмотру . Это представление покажет текущее состояние на момент обработки, которое может или не может быть связано с событием. Если обработка происходит в течение длительного времени после публикации события (например, время простоя обслуживания), тогда проблема очевидна, но она может справиться и с «исправной» обработкой, если СУБД очень быстро изменяет состояние и публикует два (или более) события в строка (что происходит часто): в этой ситуации обработка, как и в опубликованном вами коде, проверяет событие по мере его возникновения, но записывает текущее, окончательное состояние. Чтение такого аудита может быть очень запутанным позже.
- всегда проверяйте исходное событие XML. Таким образом, вы можете позже запросить этот XML для любой информации, которая не была «измельчена» в столбцы в таблице аудита.
Шаг 3: прикрепите процедуру к очереди:
alter queue dbm_notifications_queue
with activation (
status=on,
procedure_name = [dbm_notifications_procedure],
max_queue_readers = 1,
execute as owner);