машинный код x86-64, 44 байта
(Тот же машинный код работает и в 32-битном режиме.)
Ответ @Daniel Schepler был отправной точкой для этого, но у него есть по крайней мере одна новая алгоритмическая идея (а не просто лучшая игра в ту же идею): ASCII-коды для 'B'( 1000010) и 'X'( 1011000) дают 16 и 2 после маскирования с0b0010010 .
Таким образом, после исключения десятичной (ненулевая начальная цифра) и восьмеричной (символ после '0'меньше 'B'), мы можем просто установить base = c & 0b0010010и перейти в цикл цифр.
Вызывается с x86-64 System V as unsigned __int128 parse_cxx14_int(int dummy, const char*rsi); Извлеките возвращаемое значение EDX из верхней половины unsigned __int128результата с помощью tmp>>64.
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
Измененные блоки по сравнению с версией Дэниела (в основном) имеют отступ меньше, чем другие инструкции. Также основной цикл имеет свою условную ветвь внизу. Это оказалось нейтральным изменением, потому что ни один путь не мог попасть в его верхнюю часть, и dec ecx / loop .Lentryидея войти в цикл оказалась не победой после обработки восьмеричного числа по-другому. Но внутри цикла меньше инструкций с циклом в идиоматической форме do {} while struct, поэтому я сохранил его.
Испытание Даниэля C ++ в этом коде работает без изменений в 64-битном режиме, который использует то же соглашение о вызовах, что и его 32-битный ответ.
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
Разборка, включая байты машинного кода, которые являются фактическим ответом
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
Другие изменения по сравнению с версией Дэниела включают в себя сохранение sub $16, %alизнутри цифрового цикла с использованием большего subвместо testопределения разделителей, а также цифр и буквенных символов.
В отличие от Даниэля, каждый символ ниже '0'рассматривается как разделитель, а не просто '\''. (За исключением ' ': and $~32, %al/ jnzв обоих наших циклах пространство рассматривается как терминатор, что, возможно, удобно для тестирования с целым числом в начале строки.)
Каждая операция, которая изменяется %alвнутри цикла, имеет флаги потребления ветвей, установленные результатом, и каждая ветвь проходит (или проваливается) в другое место.
