Простое решение - использовать планировщик . Есть несколько реализаций. Это вкратце описывает тот, который доступен для плат на базе AVR и SAM. По сути, один вызов запускает задачу; "эскиз внутри эскиза".
#include <Scheduler.h>
....
void setup()
{
...
Scheduler.start(taskSetup, taskLoop);
}
Scheduler.start () добавит новую задачу, которая будет запускать taskSetup один раз, а затем повторно вызывать taskLoop точно так же, как работает эскиз Arduino. Задача имеет свой собственный стек. Размер стека является необязательным параметром. Размер стека по умолчанию составляет 128 байт.
Чтобы разрешить переключение контекста, необходимо вызвать yield () или delay () . Существует также макрос поддержки для ожидания условия.
await(Serial.available());
Макрос является синтаксическим сахаром для следующего:
while (!(Serial.available())) yield();
Await также может быть использован для синхронизации задач. Ниже приведен пример фрагмента:
volatile int taskEvent = 0;
#define signal(evt) do { await(taskEvent == 0); taskEvent = evt; } while (0)
...
void taskLoop()
{
await(taskEvent);
switch (taskEvent) {
case 1:
...
}
taskEvent = 0;
}
...
void loop()
{
...
signal(1);
}
Для дальнейших деталей смотрите примеры . Есть примеры от многократного мигания светодиода до кнопки отмены и простой оболочки с неблокирующим чтением командной строки. Шаблоны и пространства имен могут использоваться, чтобы помочь структурировать и уменьшить исходный код. Ниже эскиз показывает , как использовать шаблон функцию для мульти-мерцания. Для стека достаточно 64 байта.
#include <Scheduler.h>
template<int pin> void setupBlink()
{
pinMode(pin, OUTPUT);
}
template<int pin, unsigned int ms> void loopBlink()
{
digitalWrite(pin, HIGH);
delay(ms);
digitalWrite(pin, LOW);
delay(ms);
}
void setup()
{
Scheduler.start(setupBlink<11>, loopBlink<11,500>, 64);
Scheduler.start(setupBlink<12>, loopBlink<12,250>, 64);
Scheduler.start(setupBlink<13>, loopBlink<13,1000>, 64);
}
void loop()
{
yield();
}
Существует также эталон, который дает некоторое представление о производительности, то есть время запуска задачи, переключение контекста и т. Д.
Наконец, есть несколько классов поддержки для синхронизации и связи на уровне задач; Очередь и семафор .