Как мне разбить входящую строку?

Я посылаю список позиций сервопривода через последовательное соединение на Arduino в следующем формате

1:90&2:80&3:180

Который будет разбираться как:

servoId : Position & servoId : Position & servoId : Position

Как бы я разделить эти значения и преобразовать их в целое число?

Вопреки другим ответам, я бы предпочел держаться подальше Stringпо следующим причинам:

• динамическое использование памяти (это может быстро привести к фрагментации кучи и исчерпанию памяти )
• довольно медленный из-за операторов строительства / разрушения / назначения

Во встроенной среде, такой как Arduino (даже для Mega с большим количеством SRAM), я бы предпочел использовать стандартные функции C :

• strchr(): поиск символа в строке C (т.е. char *)
• strtok(): разбивает строку C на подстроки на основе символа разделителя
• atoi(): преобразует строку C в int

Это привело бы к следующему примеру кода:

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30
...

// Get next command from Serial (add 1 for final 0)
char input[INPUT_SIZE + 1];
byte size = Serial.readBytes(input, INPUT_SIZE);
// Add the final 0 to end the C string
input[size] = 0;

// Read each command pair 
char* command = strtok(input, "&");
while (command != 0)
{
    // Split the command in two values
    char* separator = strchr(command, ':');
    if (separator != 0)
    {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);

        // Do something with servoId and position
    }
    // Find the next command in input string
    command = strtok(0, "&");
}

Преимущество здесь в том, что динамическое выделение памяти не происходит; вы даже можете объявить inputкак локальную переменную внутри функции, которая будет читать команды и выполнять их; как только функция возвращается, размер, занимаемый input(в стеке), восстанавливается.

Эта функция может использоваться для разделения строки на части в зависимости от того, что символ разделяет.

String xval = getValue(myString, ':', 0);
String yval = getValue(myString, ':', 1);

Serial.println("Y:" + yval);
Serial.print("X:" + xval);

Преобразовать строку в int

int xvalue = stringToNumber(xval);
int yvalue = stringToNumber(yval);

Этот кусок кода берет строку и разделяет ее на основе заданного символа и возвращает элемент между разделяющим символом

String getValue(String data, char separator, int index)
{
    int found = 0;
    int strIndex[] = { 0, -1 };
    int maxIndex = data.length() - 1;

    for (int i = 0; i <= maxIndex && found <= index; i++) {
        if (data.charAt(i) == separator || i == maxIndex) {
            found++;
            strIndex[0] = strIndex[1] + 1;
            strIndex[1] = (i == maxIndex) ? i+1 : i;
        }
    }
    return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

Вы можете сделать что-то вроде следующего, но, пожалуйста, примите во внимание несколько вещей:

Если вы используете readStringUntil(), он будет ждать, пока не получит символ или тайм-ауты. Таким образом, с вашей текущей строкой последняя позиция будет длиться немного дольше, так как она должна ждать. Вы можете добавить трейлинг, &чтобы избежать этого тайм-аута. Вы можете легко проверить это поведение на своем мониторе, попробовать отправить строку с дополнительным значением и без него, &и вы увидите такую ​​задержку.

Вы на самом деле не нужен индекс серво, вы можете просто отправить строку позиций, и получить индекс серво по позиции значения в строке, что - то вроде: 90&80&180&. Если вы используете сервоиндекс, возможно, вы захотите проверить его (преобразовать в int, а затем сопоставить индекс цикла i), чтобы убедиться, что с вашим сообщением все в порядке.

Вы должны убедиться, что возвращаемая строка readStringUntilне пуста. Если время ожидания функции истекло, вы не получили достаточно данных, и поэтому любая попытка извлечь ваши intзначения приведет к странным результатам.

void setup() {
    Serial.begin(9600);
}

void loop() {
    for(int i=1; i<=3; i++) {
        String servo = Serial.readStringUntil(':');
        if(servo != ""){
            //here you could check the servo number
            String pos = Serial.readStringUntil('&');
            int int_pos=pos.toInt();
            Serial.println("Pos");
            Serial.println(int_pos);
        }
    }
}

Вы можете использовать Stream.readStringUntil(terminator)передачу другого терминатора для каждой части.

На каждой части вы затем позвоните String.toInt

Самое простое решение - использовать sscanf () .

  int id1, id2, id3;
  int pos1, pos2, pos3;
  char* buf = "1:90&2:80&3:180";
  int n = sscanf(buf, "%d:%d&%d:%d&%d:%d", &id1, &pos1, &id2, &pos2, &id3, &pos3);
  Serial.print(F("n="));
  Serial.println(n);
  Serial.print(F("id1="));
  Serial.print(id1);
  Serial.print(F(", pos1="));
  Serial.println(pos1);
  Serial.print(F("id2="));
  Serial.print(id2);
  Serial.print(F(", pos2="));
  Serial.println(pos2);
  Serial.print(F("id3="));
  Serial.print(id3);
  Serial.print(F(", pos3="));
  Serial.println(pos3);

Это дает следующий вывод:

n=6
id1=1, pos1=90
id2=2, pos2=80
id3=3, pos3=180

Ура!

Смотрите пример по адресу: https://github.com/BenTommyE/Arduino_getStringPartByNr

// splitting a string and return the part nr index split by separator
String getStringPartByNr(String data, char separator, int index) {
    int stringData = 0;        //variable to count data part nr 
    String dataPart = "";      //variable to hole the return text

    for(int i = 0; i<data.length()-1; i++) {    //Walk through the text one letter at a time
        if(data[i]==separator) {
            //Count the number of times separator character appears in the text
            stringData++;
        } else if(stringData==index) {
            //get the text when separator is the rignt one
            dataPart.concat(data[i]);
        } else if(stringData>index) {
            //return text and stop if the next separator appears - to save CPU-time
            return dataPart;
            break;
        }
    }
    //return text if this is the last part
    return dataPart;
}

String getValue(String data, char separator, int index)
{
    int maxIndex = data.length() - 1;
    int j = 0;
    String chunkVal = "";

    for (int i = 0; i <= maxIndex && j <= index; i++)
    {
        chunkVal.concat(data[i]);

        if (data[i] == separator)
        {
            j++;

            if (j > index)
            {
                chunkVal.trim();
                return chunkVal;
            }

            chunkVal = "";
        }
        else if ((i == maxIndex) && (j < index)) {
            chunkVal = "";
            return chunkVal;
        }
    }   
}

jfpoilpret предоставил отличный ответ для разбора последовательной команды на Arduino. Однако у Attiny85 нет двунаправленного серийного номера - необходимо использовать SoftwareSerial. Вот как вы переносите тот же код для Attiny85

#include <SoftwareSerial.h>

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30

// Initialize SoftwareSerial
SoftwareSerial mySerial(3, 4); // RX=PB3, TX=PB4

// Parameter for receiving Serial command (add 1 for final 0)
char input[INPUT_SIZE + 1];

void setup() {
  mySerial.begin(9600);
}

void loop() {
  // We need this counter to simulate Serial.readBytes which SoftwareSerial lacks
  int key = 0;

  // Start receiving command from Serial
  while (mySerial.available()) {
    delay(3);  // Delay to allow buffer to fill, code gets unstable on Attiny85 without this for some reason
    // Don't read more characters than defined
    if (key < INPUT_SIZE && mySerial.available()) {
      input[key] = mySerial.read();
      key += 1;
    }
  }

  if (key > 0) {
    // Add the final 0 to end the C string
    input[key] = 0;

    // Read each command pair
    char* command = strtok(input, "&");
    while (command != 0)
    {
      // Split the command in two values
      char* separator = strchr(command, ':');
      if (separator != 0)
      {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);
      }
      // Find the next command in input string
      command = strtok(0, "&");
    }
  }
}

Attiny85 схемы для номеров выводов

Эскиз компилируется в:

Sketch uses 2244 bytes (27%) of program storage space. Maximum is 8192 bytes.
Global variables use 161 bytes (31%) of dynamic memory, leaving 351 bytes for local variables. Maximum is 512 bytes.

Таким образом, есть много места и памяти для остальной части кода

char str[] = "1:90&2:80&3:180";     // test sample serial input from servo
int servoId;
int position;

char* p = str;
while (sscanf(p, "%d:%d", &servoId, &position) == 2)
{
    // process servoId, position here
    //
    while (*p && *p++ != '&');   // to next id/pos pair
}

void setup() {
Serial.begin(9600);
char str[] ="1:90&2:80";
char * pch;
pch = strtok(str,"&");
printf ("%s\n",pch);

pch = strtok(NULL,"&"); //pch=next value
printf ("%s\n",pch);
}
void loop(){}

Вот метод Arduino для разбиения строки в качестве ответа на вопрос «Как разбить строку в подстроке?» объявлен дубликатом настоящего вопроса.

Задача решения - проанализировать серию позиций GPS, записанных в файл SD-карты . Вместо того, чтобы получить строку, полученную из Serial, строка читается из файла.

Функция StringSplit()разбирает строку sLine = "1.12345,4.56789,hello"на 3 строки sParams[0]="1.12345", sParams[1]="4.56789"& sParams[2]="hello".

1. String sInput: входные строки для анализа,
2. char cDelim: символ разделителя между параметрами,
3. String sParams[]: выходной массив параметров,
4. int iMaxParams: максимальное количество параметров,
5. Вывод int: количество проанализированных параметров,

Функция основана на String::indexOf()и String::substring():

int StringSplit(String sInput, char cDelim, String sParams[], int iMaxParams)
{
    int iParamCount = 0;
    int iPosDelim, iPosStart = 0;

    do {
        // Searching the delimiter using indexOf()
        iPosDelim = sInput.indexOf(cDelim,iPosStart);
        if (iPosDelim > (iPosStart+1)) {
            // Adding a new parameter using substring() 
            sParams[iParamCount] = sInput.substring(iPosStart,iPosDelim-1);
            iParamCount++;
            // Checking the number of parameters
            if (iParamCount >= iMaxParams) {
                return (iParamCount);
            }
            iPosStart = iPosDelim + 1;
        }
    } while (iPosDelim >= 0);
    if (iParamCount < iMaxParams) {
        // Adding the last parameter as the end of the line
        sParams[iParamCount] = sInput.substring(iPosStart);
        iParamCount++;
    }

    return (iParamCount);
}

И использование действительно просто:

String sParams[3];
int iCount, i;
String sLine;

// reading the line from file
sLine = readLine();
// parse only if exists
if (sLine.length() > 0) {
    // parse the line
    iCount = StringSplit(sLine,',',sParams,3);
    // print the extracted paramters
    for(i=0;i<iCount;i++) {
        Serial.print(sParams[i]);
    }
    Serial.println("");
}