Applescript для добавления отправителя сообщения в определенную группу в Контактах

Я пытаюсь настроить Applescript для добавления отправителя выбранного сообщения в Apple Mail в определенную группу в приложении «Контакты». Переконфигурировав код, приведенный в этом ответе , я решил следующее, но оно не работает. Любые предложения о том, что я делаю не так?

    tell application "Mail"
    set theMessage to selection
    tell application "Contacts"
        set theGroup to "_TEST"
    end tell
    set theSender to sender of theMessage
    tell application "Contacts"
        set theName to name of theSender
        set thePerson to make new person with properties {first name:name of theSender}
        add thePerson to theGroup
    end tell
    tell application "Contacts" to save
    end tell

Попробуйте это, он создаст контакт с правильным именем, фамилией и адресом электронной почты:

tell application "Mail"
set theMessages to selection
if theMessages is not {} then -- check empty list
    set theSenderName to extract name from sender of item 1 of theMessages
    set nameArray to my split(theSenderName, " ")
    set theFirstName to item 1 of nameArray
    set theLastName to last item of nameArray
    set theEmail to extract address from sender of item 1 of theMessages

    tell application "Contacts"
        set theGroup to group "_TEST"
        set thePerson to make new person with properties {first name:theFirstName, last name:theLastName}
        make new email at end of emails of thePerson with properties {label:"Work", value:theEmail}
        add thePerson to theGroup
        save
    end tell
    end if
end tell

on split(theString, theDelimiter)
    set oldDelimiters to AppleScript's text item delimiters
    set AppleScript's text item delimiters to theDelimiter
    set theArray to every text item of theString
    set AppleScript's text item delimiters to oldDelimiters
    return theArray
end split

Было несколько проблем с вашей первоначальной попыткой, вот как я их обошел.

• Для начала, selectionдает вам список элементов (даже если это просто список из одного), поэтому вам нужно выбрать первый элемент из выбора.
• В почте senderвыдает не очень полезную строку, объединяющую имя и адрес электронной почты. extract name fromи extract address fromдать вам полезные строки.
• Строка имени является полным именем, но Contacts.app ожидает отдельное имя и фамилию, поэтому я разделил эту строку (используя удобную функцию, найденную здесь ), чтобы сделать правильное предположение по имени и фамилии. Это может дать неожиданные результаты от странно отформатированных имен в электронных письмах.

Если у вас есть какие-либо проблемы с этим, дайте мне знать, и я посмотрю, смогу ли я их исправить. В будущем, возможно, будет полезно запустить сценарии в редакторе AppleScript и проверить журнал событий для получения подробной информации о том, что не работает (сообщения об ошибках полезны, хотя бы для того, чтобы поместить их в Google или дать другим отправную точку для решения вашей проблемы).

У меня есть более расширенная версия этой идеи, которая представляет список групп и позволяет выбирать из него; он также обрабатывает несколько сообщений. Вы можете добавить отправителя нескольких разных сообщений в одну группу или добавить одного или нескольких отправителей в несколько групп.

В моем сценарии для добавления отправителя к контактам используется сочетание клавиш: Cmd-Shift-Y (выполняется сценарием, но держу пари, что вы не знали, что это было с помощью сочетания клавиш !! Это происходит в меню «Сообщения», когда сообщение выбрано).

tell application "Mail" to set theSelection to selection
  if theSelection is {} then return beep 2
  if length of theSelection = 1 then
    set thePrompt to "Select the group(s) to which to add the sender of the selected message."
  else
    set thePrompt to "Select the group(s) to which to add the senders of the selected messages."
  end if
tell application "Contacts" to set theList to name of groups
set R to choose from list theList with prompt thePrompt with multiple selections allowed
if R is false then return

tell application "Mail"
    activate
    set theSenders to {}
    repeat with thisMessage in theSelection
        set theSender to extract name from sender of thisMessage
        copy theSender to the end of theSenders
    end repeat
    tell application "System Events" to keystroke "y" using {shift down, command down}
end tell

tell application "Contacts"
    activate
    repeat with thisSender in theSenders
        delay 0.1
        set thePersons to (people whose value of emails contains (thisSender as text))
        if (count thePersons) = 1 then
            repeat with theGroupName in items of R
                add (item 1 of thePersons) to group theGroupName
            end repeat
        else
            repeat with theGroupName in items of R
                repeat with thisPerson in thePersons
                    add thisPerson to group theGroupName
                end repeat
            end repeat
        end if
    end repeat
    save
    set selected of group theGroupName to true
    tell application "System Events" to keystroke "0" using {command down}
end tell