Есть ли способ отображения вывода AppleScript в строке меню?

Прежде чем читать дальше: я знаю про дворецкого и подобные программы. Я ищу встроенный способ сделать это без стороннего приложения.

Во всяком случае, я написал AppleScript, который запускает команду оболочки. Я хочу отобразить этот вывод в строке меню вверху ... без Батлера, как я могу это сделать?

Как правило, без сторонней программы, такой как Growl, не существует встроенного способа сделать это.

Тем не менее, вы можете написать скрипт или другую программу, такую ​​как я нашел здесь, которая предоставляет вам сервис меню. Я уверен, что интеграция Growl будет гораздо проще осуществить.

В OS X нет встроенного способа сделать это. Однако, используя Growl , вы можете получать уведомления. Вот пример сценария для этого:

--Make sure Growl is running
tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

if isRunning then
    tell application id "com.Growl.GrowlHelperApp"
        set the allNotificationsList to ¬
            {"Test Notification", "Another Test Notification"}
        --Notifications can be enabled in System Preferences>Growl>Applications>Display Options
        set the enabledNotificationsList to ¬
            {"Test Notification"}
        register as application ¬
            "Growl AppleScript Sample" all notifications allNotificationsList ¬
            default notifications enabledNotificationsList ¬
                    -- Set the icon. You can use any icon from any application
            icon of application "AppleScript Editor"

        notify with name ¬
            "Test Notification" title ¬
            "Test Notification" description ¬
            "This is a test AppleScript notification." application name "Growl AppleScript Sample"

        notify with name ¬
            "Another Test Notification" title ¬
            "Another Test Notification :) " description ¬
            "Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample"

    end tell
end if

Это должно отобразить это:

И если у вас включено другое уведомление:

Более продвинутые методы описаны здесь.

Поскольку AppleScriptObjC является частью macOS, можно использовать его основу (включая методы NSMenu) для достижения того, что, вероятно, было невозможно в 2012 году.

Я нашел интересный скрипт для создания пользовательских меню из AppleScript; Из этого я извлек подходящий код для размещения текста в строке меню macOS . Фактически он использует только «заголовок» меню для вставки некоторого контента.

Чтобы продемонстрировать это, я реализовал очень простой диалоговый скрипт, который запрашивает у пользователя ввод текста (ожидание 6 секунд), который затем временно отображается в строке меню (5 секунд).
Вот:

use framework "Foundation"
use framework "AppKit"
use scripting additions
property StatusItem : missing value
property newMenu : class "NSMenu"

display dialog "Write something:" default answer "" giving up after 6
set myText to text returned of the result
if myText is "" then set myText to "TOOOOO slow … try again !"
set myText to ">>    " & myText & "    <<"

set bar to current application's NSStatusBar's systemStatusBar
set StatusItem to bar's statusItemWithLength:-1.0
StatusItem's setTitle:myText
set newMenu to current application's NSMenu's alloc()'s initWithTitle:"Custom"
StatusItem's setMenu:newMenu

delay 5
current application's NSStatusBar's systemStatusBar()'s ¬
        removeStatusItem:StatusItem  

Этот код AppleScript можно использовать в любом вашем скрипте. (Его «диалоговая» часть необязательна…)

user3439894 помог с закрытием моего "меню", см. последнюю строку скрипта. Большое спасибо!