Добавление закладок для нескольких вкладок в Safari с помощью сочетания клавиш

В Safari есть Add Bookmarks for These N Tabs…функция. К сожалению, вы не можете создать комбинацию клавиш для этого, потому что они должны соответствовать названию пункта меню.

Вы можете использовать этот Applescript; он создает скрипт оболочки, содержащий ссылки для всех вкладок в текущем окне Safari:

-- Set the default folder to Home -> bookmarks
set bookmarkFolder to "/bookmarks"
set username to do shell script "whoami"
set defaultFolder to POSIX file ("/Users/" & username & bookmarkFolder)

-- Initialize the text ot the script.
set cmd to "#!/bin/bash" & linefeed & linefeed

-- Add commands to open all the tabs.
tell application "Safari"
    set n to count of tabs in front window
    repeat with i from 1 to n
        set cmd to cmd & "open -g " & URL of tab i of front window & linefeed
    end repeat
end tell

-- Open/create a file and save the script.

tell me
    activate
    set scriptAlias to choose file name default name "tabset" default location (defaultFolder as alias)
end tell
set scriptPath to quoted form of POSIX path of scriptAlias
set scriptFile to open for access scriptAlias with write permission
set eof scriptFile to 0
write cmd to scriptFile starting at eof
close access scriptFile

-- Change the file attributes to make it double-clickable.
do shell script "chmod 777 " & scriptPath
do shell script "xattr -wx com.apple.FinderInfo '00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00' " & scriptPath

Оригинальная версия написана доктором Дрангом .

Я изменил две вещи:

• скрипт учитывает пробелы в имени файла
• папка по умолчанию ~/bookmarks

Для того, чтобы запустить его, вы можете использовать пусковую (например , Quicksilverили Butler) или обернуть его в System Serviceс Automator:

• создать сервис
  • добавить Run Applescriptпредмет
  • выберите Service receives нет ввода in Safari
  • вставьте Applescript
• создать ярлык в System Preferences > Keyboard > Shortcuts > Services
  • ⌘⌥D не работает, если вы используете его для переключения видимости дока