В настоящее время я использую OS X (10.9.1) и только что попробовал сочетание клавиш ⌘+ ⇧+ .в диалоговом окне сохранения, и оно работало просто отлично.
Я также настроил AppleScript на своем компьютере с помощью сочетания клавиш ^+ ⌘+ ⇧+, .который переключает видимость скрытых файлов в Finder, когда я хочу. Таким образом, мне не нужно вручную запускать команду терминала для отображения скрытых файлов, и я могу быстро отключить ее, чтобы избежать случайного изменения системных файлов. Я использую FastScripts (также доступны в Mac App Store ), чтобы позволить мне установить сочетание клавиш для моего AppleScript, и поместил AppleScript в мою ~/Library/Scriptsпапку.
Обновить
Я обновил свой скрипт, так что Finder не нужно убивать каждый раз, когда вы хотите показать / скрыть отображение скрытых файлов. Как отметил markhunte, вы можете переключать состояние просмотра окна Finder, что обновит список содержимого. Спасибо Маркхунту за то, что указал мне на это! Вот обновленный скрипт:
(*
Author: Anil Natha
Description:
This script toggles the visibility of hidden files in OS X. This includes
showing hidden files in Finder windows and on the desktop.
Last Updated: 2015-02-20
*)
tell application "System Events"
try
set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
on error
set hiddenFilesDisplayStatus to "NO"
end try
set hiddenFilesNewDisplayStatus to "NO"
if hiddenFilesDisplayStatus is "NO" then
set hiddenFilesNewDisplayStatus to "YES"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
end tell
tell application "Finder"
set allWindows to windows
repeat with currentWindow in allWindows
set currentWindowView to get the current view of the currentWindow
set alternateWindowView to list view
if currentWindowView is list view then
set alternateWindowView to icon view
end if
set the current view of the currentWindow to alternateWindowView
set the current view of the currentWindow to currentWindowView
end repeat
end tell
Старая версия скрипта указана ниже. Хотя это работает, я не рекомендую использовать его больше сейчас, так как приведенный выше скрипт работает более эффективно.
tell application "System Events"
set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
set hiddenFilesNewDisplayStatus to "NO"
if hiddenFilesDisplayStatus is "NO" then
set hiddenFilesNewDisplayStatus to "YES"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
do shell script "killall Finder"
end tell